parm interval = 30                                                      
echo Wait interval is !interval seconds unless interrupted              
echo                                                                    
echo QPLUS has begun.  Syntax = :QPLUS or QPLUS #waitcycleseconds       
echo                                                                    
WHILE HPCONNSECS > 0                                                    
   IF FINFO("SQMSG",0)                                                  
      PURGE SQMSG,TEMP                                                  
   ENDIF                                                                
   BUILD SQMSG;REC=-79,,F,ASCII;TEMP;MSG                                
   FILE SQMSG=SQMSG,OLDTEMP                                             
   SHOWQ;ACTIVE >*SQMSG                                                 
   SETVAR PINLIST ""                                                    
   WHILE FINFO("SQMSG",19) <> 0                                         
        INPUT SQLINE < SQMSG                                            
        IF POS("#",SQLINE) <> 0 THEN                                    
          SETVAR PIN RTRIM(STR(SQLINE,47,5))                            
          SETVAR PINLIST "!PINLIST" + "," + "!PIN"                      
        ENDIF                                                           
   ENDWHILE                                                             
   IF FINFO("SPMSG",0)                                                  
      PURGE SPMSG,TEMP                                                  
   ENDIF                                                                
   BUILD SPMSG;REC=-79,,F,ASCII;TEMP;MSG                                
   FILE SPMSG=SPMSG,OLDTEMP                                             
   SETVAR PROC "SHOWPROC PIN=" + "!PINLIST" + ";SYSTEM >*SPMSG"         
   CONTINUE                                                             
   !PROC                                                                
   WHILE FINFO("SPMSG",19) <> 0                                         
        INPUT SPLINE < SPMSG                                            
        IF POS(":",SPLINE) <> 0 THEN                                    
          ECHO !SPLINE                                                  
        ENDIF                                                           
   ENDWHILE                                                             
   setvar dummy,"X"                                                     
   setvar hpmsgfence,1                                                  
   input dummy;prompt="ENTER 'E' or 'e' to exit->";wait=!interval       
   setvar hpmsgfence,0                                                  
   ECHO                                                                 
   ECHO                                                                 
   if dummy="E" or dummy = "e" then                                     
     RETURN                                                             
   endif                                                                
   deletevar dummy                                                      
ENDWHILE