!job gateway,manager.sys;outclass=lp,1
!comment
!comment  This job will monitor the gateway at IP address
!comment  192.1.1.1 If it goes down it will automatically
!comment  bring it back up.
!comment
!setvar Router,"192.1.1.1"
!setvar waittime,45
!while 1 = 1
!   purge netout,temp >$null
!   build netout;temp;rec=-80,,f,ascii;nocctl;msg
!   file netout,oldtemp;dev=disc
!   nettool.net.sys "nam;rou;gatelist;quit" >*netout
!   setvar gaterec," "
!   reset netout
!   while finfo("netout","eof") > 0
!       input gaterec <netout
!       setvar gateip, rtrim(str(gaterec,1,15))
!       if gateip = "!router"
!          setvar gatestatus,str(gaterec,40,1)
!          if gatestatus = "n" then
!             Tellop *********************************************
!             Tellop ***  Router at !router is down !!! 
!             Tellop ***
!             Tellop ***  I will re-enable                
!             Tellop ***            
!             Tellop *********************************************
!             nettool.net.sys "nam;rou;gateup !router;quit"
!          else
!             echo !HPTimef and all is well.
!             echo
!          endif
!      endif
!   endwhile
!   pause !waittime
!endwhile
!eoj