COMMENT 'FOOTERS' A FILE CONTAINING SEVERAL USEFUL HP3000 MPE/iX
COMMENT           COMMAND FILE SCRIPTS.
PARM FILE, ITEM, LISTCODE=NOLIST
COMMENT "FOOTAT", QUIZ: Count all various ITEM values in FILE
COMMENT JFB 02/06/1997
COMMENT SET WORKING VARIABLE TO BLANKS
COMMENT
SETVAR _CSTAT," "
SETVAR _CSTATX," "
SETVAR _SSTAT," "
SETVAR _SSTATX," "
ECHO ACCESS !FILE > TQ1
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A CHOOSE STATEMENT
COMMENT
INPUT _CSTATX;PROMPT="Want to specify CHOOSE ? (Y/N)->";WAIT=3
IF _CSTATX = "Y"
  INPUT _CSTAT;PROMPT="Enter CHOOSE statement or CR->";WAIT=90
  ECHO !_CSTAT >> TQ1
ENDIF
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A SELECT STATEMENT
COMMENT
INPUT _SSTATX;PROMPT="Want to specify SELECT ? (Y/N)->";WAIT=3
IF _SSTATX = "Y"
  INPUT _SSTAT;PROMPT="Enter SELECT statement or CR->";WAIT=90
  ECHO !_SSTAT >> TQ1
ENDIF
ECHO SORT ON !ITEM >> TQ1
ECHO REPORT >> TQ1
ECHO FOOT AT !ITEM COUNT RESET AT !ITEM PIC "^,^^^,^^^" !ITEM >> TQ1
ECHO FIN FOO SKI 1 & >> TQ1
ECHO "===============================================" SKI 1 & >> TQ1
ECHO COUNT "= # records reported.  (Rep limit = 500,000)" >> TQ1
ECHO SET REP LIM 500000 >> TQ1
ECHO SET PAG LEN 0 >> TQ1
ECHO SET NOSTATISTICS >> TQ1
ECHO GO >> TQ1
ECHO EXIT >> TQ1
COMMENT
COMMENT CLEANUP OUR VARIABLES
COMMENT
DELETEVAR _CSTAT
DELETEVAR _CSTATX
DELETEVAR _SSTAT
DELETEVAR _SSTATX
ECHO *** Now using 'FOOTAT' created code in temp file 'TQ1'... ***
QUIZ "AUTO=TQ1 !LISTCODE"




PARM FILE, ITEM, COUNTSORT="A", LISTCODE=NOLIST
COMMENT "FOOTATSB", QUIZ: Count all various ITEM values in FILE
COMMENT   and subfile this info in temp subfile "TQ1SUB".  Then
COMMENT   report this info in either A or D order based upon count.
COMMENT JFB 07/13/1998
COMMENT
COMMENT PURGE TEMPORARY SUBFILE USED
CONTINUE
PURGE TQ1SUB,TEMP
COMMENT
COMMENT SET WORKING VARIABLE TO BLANKS
SETVAR _CSTAT," "
SETVAR _CSTATX," "
SETVAR _SSTAT," "
SETVAR _SSTATX," "
ECHO ACCESS !FILE > TQ1
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A CHOOSE STATEMENT
COMMENT
INPUT _CSTATX;PROMPT="Want to specify CHOOSE ? (Y/N)->";WAIT=5
IF _CSTATX = "Y"
  INPUT _CSTAT;PROMPT="Enter CHOOSE statement or CR->";WAIT=90
  ECHO !_CSTAT >> TQ1
ENDIF
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A SELECT STATEMENT
COMMENT
INPUT _SSTATX;PROMPT="Want to specify SELECT ? (Y/N)->";WAIT=3
IF _SSTATX = "Y"
  INPUT _SSTAT;PROMPT="Enter SELECT statement or CR->";WAIT=90
  ECHO !_SSTAT >> TQ1
ENDIF
ECHO SORT ON !ITEM >> TQ1
ECHO DEFINE !["!ITEM" + "-COUNT"] NUM*9 = 1 >> TQ1
ECHO REPORT SUMMARY & >> TQ1
ECHO   !["!ITEM" + "-COUNT"] SUBTOTAL RESET AT !ITEM !ITEM >> TQ1
ECHO SET SUBFILE NAME TQ1SUB AT !ITEM >> TQ1
ECHO SET REP LIM 500000 >> TQ1
ECHO SET PAG LEN 0 >> TQ1
ECHO SET NOSTATISTICS >> TQ1
ECHO GO >> TQ1
ECHO EXIT >> TQ1
COMMENT
COMMENT CLEANUP OUR VARIABLES
COMMENT
DELETEVAR _CSTAT
DELETEVAR _CSTATX
DELETEVAR _SSTAT
DELETEVAR _SSTATX
ECHO *** Now using 'FOOTATSB' created code in temp file 'TQ1'... ***
RUN QUIZ.PH709E.COGNOS;INFO="AUTO=TQ1 !LISTCODE"
ECHO ACCESS *TQ1SUB > TQ2
ECHO SORT ON !["!ITEM" + "-COUNT" + " !COUNTSORT"]  >> TQ2
ECHO REPORT !["!ITEM" + "-COUNT"] !ITEM >> TQ2
ECHO FIN FOO SKI 1 & >> TQ2
ECHO "===============================================" SKI 1 & >> TQ2
ECHO COUNT "different !ITEM values were just listed." SKI 2 & >> TQ2
ECHO "(Note: FOOTATSB report limit = 500,000)" SKI 2 & >> TQ2
ECHO "Temp subfile TQ1SUB was reported in !COUNTSORT order." >> TQ2
ECHO SET REP LIM 500000 >> TQ2
ECHO SET PAG LEN 0 >> TQ2
ECHO SET NOSTATISTICS >> TQ2
ECHO GO >> TQ2
ECHO EXIT >> TQ2
RUN QUIZ.PH709E.COGNOS;INFO="AUTO=TQ2 !LISTCODE"
PARM FILE, ITEM, LISTCODE=NOLIST
COMMENT "FOOTFIN", QUIZ: Count total # unique ITEM values in FILE
COMMENT JFB 02/06/1997
COMMENT SET WORKING VARIABLE TO BLANKS
COMMENT
SETVAR _CSTAT," "
SETVAR _CSTATX," "
SETVAR _SSTAT," "
SETVAR _SSTATX," "
ECHO ACCESS !FILE > TQ1
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A CHOOSE STATEMENT
COMMENT
INPUT _CSTATX;PROMPT="Want to specify CHOOSE ? (Y/N)->";WAIT=3
IF _CSTATX = "Y"
  INPUT _CSTAT;PROMPT="Enter CHOOSE statement or CR->";WAIT=90
  ECHO !_CSTAT >> TQ1
ENDIF
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A SELECT STATEMENT
COMMENT
INPUT _SSTATX;PROMPT="Want to specify SELECT ? (Y/N)->";WAIT=3
IF _SSTATX = "Y"
  INPUT _SSTAT;PROMPT="Enter SELECT statement or CR->";WAIT=90
  ECHO !_SSTAT >> TQ1
ENDIF
ECHO SORT ON !ITEM >> TQ1
ECHO REP >> TQ1
ECHO FIN FOO SKI 1 & >> TQ1
ECHO "===============================================" SKI 1 & >> TQ1
ECHO COUNT AT !ITEM 'unique' '!ITEM' 'exist in' '!FILE' & >> TQ1
ECHO SKI 2 COUNT "= # records reported. (Rep limit = 500,000)"  >> TQ1
ECHO SET REP LIM 500000 >> TQ1
ECHO SET PAG LEN 0 >> TQ1
ECHO SET NOSTATISTICS NOHEAD >> TQ1
ECHO GO >> TQ1
ECHO EXIT >> TQ1
COMMENT
COMMENT CLEANUP OUR VARIABLES
COMMENT
DELETEVAR _CSTAT
DELETEVAR _CSTATX
DELETEVAR _SSTAT
DELETEVAR _SSTATX
ECHO *** Now using 'FOOTFIN' created code in temp file 'TQ1'... ***
QUIZ "AUTO=TQ1 !LISTCODE"
PARM FILE, HITEM, FITEM, LISTCODE=NOLIST
COMMENT "FOOTHEAD", QUIZ: Count all various FITEM values in FILE
COMMENT             within each HITEM value with Heading at HITEM
COMMENT JFB 02/06/1997
COMMENT SET WORKING VARIABLEs TO BLANKS
COMMENT
SETVAR _CSTAT," "
SETVAR _CSTATX," "
SETVAR _SSTAT," "
SETVAR _SSTATX," "
ECHO ACCESS !FILE > TQ1
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A CHOOSE STATEMENT
COMMENT
INPUT _CSTATX;PROMPT="Want to specify CHOOSE ? (Y/N)->";WAIT=3
IF _CSTATX = "Y"
  INPUT _CSTAT;PROMPT="Enter CHOOSE statement or CR->";WAIT=90
  ECHO !_CSTAT >> TQ1
ENDIF
COMMENT
COMMENT PROVIDE OPPORTUNITY TO ENTER A SELECT STATEMENT
COMMENT
INPUT _SSTATX;PROMPT="Want to specify SELECT ? (Y/N)->";WAIT=3
IF _SSTATX = "Y"
  INPUT _SSTAT;PROMPT="Enter SELECT statement or CR->";WAIT=90
  ECHO !_SSTAT >> TQ1
ENDIF
ECHO SORT ON !HITEM ON !FITEM >> TQ1
ECHO REPORT >> TQ1
ECHO HEAD AT !HITEM SKI 2 "**" "!HITEM" "=" !HITEM "**" SKI 1 >> TQ1
ECHO FOO AT !FITEM COU RESET AT !FITEM PIC "^,^^^,^^^" !FITEM >> TQ1
ECHO FIN FOO SKI 1 & >> TQ1
ECHO "===============================================" SKI 1 & >> TQ1
ECHO COU AT !HITEM "= # unique !HITEM reported" & >> TQ1
ECHO SKI 2 COUNT "= # records reported. (Rep limit = 500,000)" >> TQ1
ECHO SET REP LIM 500000 >> TQ1
ECHO SET PAG LEN 0 >> TQ1
ECHO SET NOSTATISTICS >> TQ1
ECHO GO >> TQ1
ECHO EXIT >> TQ1
COMMENT
COMMENT CLEANUP OUR VARIABLES
COMMENT
DELETEVAR _CSTAT
DELETEVAR _CSTATX
DELETEVAR _SSTAT
DELETEVAR _SSTATX
ECHO *** Now using 'FOOTHEAD' created code in temp file 'TQ1'... ***
QUIZ "AUTO=TQ1 !LISTCODE"