SETVAR EXCEPT1 "MANAGER.SYS"                                            
SETVAR EXCEPT2 "OPERATOR.SYS"                                           
ECHO THIS WILL ABORT ALL SESSIONS AND JOBS, WITH THE EXCEPTION OF:      
ECHO   THE CURRENT JOB OR SESSION!                                      
ECHO   !EXCEPT1                                                         
ECHO   !EXCEPT2                                                         
ECHO                                                                    
ECHO ARE YOU A WIZARD?                                                  
INPUT QUESTION                                                          
IF QUESTION ="XYXXY" THEN                                               
   IF FINFO("SJMSG",0)                                                  
      PURGE SJMSG,TEMP                                                  
   ENDIF                                                                
   BUILD SJMSG;REC=-79,,F,ASCII;TEMP;MSG                                
   FILE SJMSG=SJMSG,OLDTEMP                                             
   SHOWJOB JOB=@;*SJMSG                                                 
   SETVAR COUNT FINFO("SJMSG",19)                                       
   SETVAR MYJOB "#" + "!HPJOBTYPE"+ "!HPJOBNUM"                         
   WHILE FINFO("SJMSG",19) <> 0                                         
        INPUT SJLINE < SJMSG                                            
        IF STR(SJLINE,1,1) = "#" THEN                                   
        ECHO !SJLINE                                                    
            IF STR(SJLINE,1,LEN(MYJOB)) = MYJOB THEN                    
                 ECHO  !MYJOB NOT ABORTED! CURRENT SESSION!             
            ELSE                                                        
                 IF POS(EXCEPT1,SJLINE) <> 0 THEN                       
                       ECHO !EXCEPT1 EXCEPT#1 NOT ABORTED!              
                 ELSE                                                   
                      IF POS(EXCEPT2,SJLINE) <> 0 THEN                  
                            ECHO !EXCEPT2 EXCEPT#2 NOT ABORTED!         
                      ELSE                                              
                            SETVAR C STR(SJLINE,1,7)                    
                            SETVAR B "ABORTJOB "                        
                            SETVAR B B + C                              
                            ECHO !B                                     
                            !B                                          
                            CONTINUE                                    
                      ENDIF                                             
                ENDIF                                                   
            ENDIF                                                       
        ENDIF                                                           
   ENDWHILE                                                             
ENDIF